以太坊开发演练,Part-1:智能合约

    智能合约,众筹,Mist,Metamask,Remix,geth,web3……如果你花过一点时间尝试了解以太坊的开发,你大概对这些并不陌生。

    一些人在测试网络中部署智能合约,另一些人告诉你要读黄皮书,而另一些人则建议你使用 truffle 套件,因为它很有帮助。但其实你并不知道该做什么,也不知道这些东西放在一起是怎么用的。

    如果这是你读到的第一篇关于以太坊或区块链生态系统的文章,你会爱上以太坊的!虽然“专家们”在twitter上互掐,有很多不安全的标准和协议,未经测试有bug的开发工具……并不是所有的问题都已经解决,但每个人都在朝着不同的方向前进探索,任重而道远。机构、银行和政府的未来将由这些疯狂的开发者决定!这真是太棒了。

    不管怎样,别担心,我会努力把本系列教程中所有的信息点串连起来,带你走进智能合约和 dapps 的开发世界,向你展示各部分是如何配合工作的。

    虽然我不会对每一个细节进行阐释,但我会给你一些阅读材料的链接,这些材料能帮助你更好地理解某些概念,这要靠你自己研究并了解所有的细节。这个系列的目的就是以最简单的方式,帮助你更好地理解各部分是如何协同工作的,就像一个朋友向你解释说明那样。

    我甚至不知道以太坊是什么

    以太坊的官方网站告诉我们:

    以太坊是一个运行着智能合约的分布式平台:应用程序完全按照程序运行,不存在故障、审查、欺诈或第三方干预的可能性。

    换句话说,以太坊给予了我们使用区块链技术来验证我们运行的代码的执行情况的能力。

    如果你不知道区块链、以太坊、比特币、加密货币这些词的含义,我建议你听听Tim Ferriss采访Nick Szabo和Naval Ravikant的精彩播客:沉默的加密货币大师——Nick Szabo

    智能合约是什么?

    在以太坊,智能合约是可以处理资金的脚本。就是这么简单。

    这些合约由我们称为“矿工”的参与方强制执行和证明。矿工其实是多台电脑,它们把一项交易(执行智能合约,支付加密货币等) 添加到一个公开分类账上,我们称之为区块。多个区块构成一个区块链。

    我们给这些矿工支付一种叫作 “Gas” 的东西,它是运行一份合约的成本。当你发布一份智能合约,或者执行一份智能合约,或者把钱转到另一个账户,你就要支付一些被转换成Gas的以太币。

    如果你还不清楚,或者想知道更多的细节,这里有一些有趣的链接:

    在深入智能合约的开发之前

    在本教程中,我会假设你已经在软件开发方面有了一定的基础,并且具备了 Javascript 和 Node.JS 的基本知识。否则,你很快会看不懂。Solidity 是我们用来开发的编程语言,它与 Javascript 的语法非常接近,而且由于以太坊周围很多的开发工具都是基于 Javascrip 和 Node . JS. 的,所以如果你对两者都已经很熟悉的话,那你就更容易理解。这不是针对初学者的教程,如果你不理解一些概念,我会为给你一些替代教程的链接,剩下的部分靠你自己研究吃透。

    智能合约开发

    现在,我们开始有趣的部分,正如我所说的,Solidity 与 Javascript 很接近,但它们并不相同。关于 Solidity,我很遗憾地告诉你,作为前端开发人员,你不能在一段代码上强加 JQuery 并希望它能起作用,你不能忽略安全性,不能“另辟蹊径”。我们会在讨论安全性、开发模式和防止代码故障的时候知晓原因。

    现在,关于我们的第一个例子,我正在考虑一个由电影《时间规划局》启发的脚本。电影中,人们生活在一个反乌托邦式的未来,改用时间作为货币流通。他们可以通过掰手腕的方式赢取对手的时间(他们的“手臂”上存储着时间,输方的时间将会传送给赢家),我们也可以这么做!用智能合约以角力( Wrestling )的方式赚钱。

    别担心,我会在Github上为你提供接下来我们会看到的所有脚本。

    另外,如果这是你第一次处理智能合约,如果你现在不了解所有的事情那也没关系,你需要练习、阅读文档和做一些研究来熟悉Solidity。

    代码

    现在话题转到写代码上,首先,solidity 脚本的基础是下面这段代码,pragma 指令会告诉编译器我们正在使用的 Solidity 版本,以及我们的合约名称,是一种与 Javascrip 上的类(class)相似的结构。这就是“Wrestling(角力)”。

    pragma solidity ^0.4.18;
    
    contract Wrestling {
        // our code will go here
    }

    我们需要两个参与者,所以我们要添加两个保存他们账户地址的变量(他们钱包的公钥)。

    address public wrestler1;
    address public wrestler2;

    在我们的小游戏中,每一轮的比赛,参与者都可以投入一笔钱,如果一个人投入的钱是另一个人的两倍(总计),那他就赢了。

    bool public wrestler1Played;
    bool public wrestler2Played;
    
    uint private wrestler1Deposit;
    uint private wrestler2Deposit;
    
    bool public gameFinished; 
    address public theWinner;
    uint gains;

    关于公钥/私钥的一件重要的事项是,即使一个变量是私有的,但并不意味着其他人不能读取它的内容,它只是意味着它只能在合约中被访问,但实际上,由于整个区块链存储在许多计算机上,所以存储在变量中的信息总是可以被其他人看到,这是你应该记住的第一个安全考虑。

    另一方面,编译器会自动为公共变量创建 getter 函数。为了使其他的合约和用户能够更改公共变量的值,你需要创建一个 setter 函数。

    现在我们将为游戏的每一步添加三个事件。开始,参与者注册;游戏期间,登记每一轮赛果;最后,其中一位参与者获胜。事件是简单的日志,可以在分布式应用程序(也称为 dapps)的用户界面中调用 JavaScript 回调函数。在开发过程中,事件甚至可以用于调试的目的,因为它不同于 JavaScript 在 Solidity上 的 console.log() 函数。

    event WrestlingStartsEvent(address wrestler1, address wrestler2);
    event EndOfRoundEvent(uint wrestler1Deposit, uint wrestler2Deposit);
    event EndOfWrestlingEvent(address winner, uint gains);

    现在我们将添加构造函数,在 Solidity 中,它与我们的合约具有相同的名称,并且在创建合约时只调用一次。

    在这里,第一位参与者将是创造合约的人。“msg.sender” 是调用该函数的人的地址。

    function Wrestling() public {
      wrestler1 = msg.sender;
    }

    接下来,我们让另一个参与者使用以下函数进行注册:

    function registerAsAnOpponent() public {
        require(wrestler2 == address(0));
    
        wrestler2 = msg.sender;
    
        WrestlingStartsEvent(wrestler1, wrestler2);
    }

    require 函数是 Solidity 中一个特殊的错误处理函数,如果条件不满足,它会回滚更改。在我们的示例中,如果变量参与者2等于0x0地址(地址等于0),我们可以继续;如果参与者2的地址与0x0地址不同,这就意味着某个玩家已经注册为对手,所以我们会拒绝新的注册。

    再次强调, “msg.sender”是调用该函数的帐户地址,并且当我们触发一个事件,就标志着角力的开始。

    现在,每一个参与者都会调用一个函数,“wrestle()”,并投入资金。如果双方已经玩过这场游戏,我们就能知道其中一方是否获胜(我们的规则是其中一方投入的资金必须是另一方的双倍)。关键字“payable”意味着函数可以接收资金,如果它不是集合,函数则不会接受以太币。“msg.value”是发送到合约中的以太币的数量。

        function wrestle() public payable {
            require(!gameFinished && (msg.sender == wrestler1 || msg.sender == wrestler2));
    
            if(msg.sender == wrestler1) {
                require(wrestler1Played == false);
                wrestler1Played = true;
                wrestler1Deposit = wrestler1Deposit + msg.value;
            } else { 
                require(wrestler2Played == false);
                wrestler2Played = true;
                wrestler2Deposit = wrestler2Deposit + msg.value;
            }
            if(wrestler1Played && wrestler2Played) {
                if(wrestler1Deposit >= wrestler2Deposit * 2) {
                    endOfGame(wrestler1);
                } else if (wrestler2Deposit >= wrestler1Deposit * 2) {
                    endOfGame(wrestler2);
                } else {
                    endOfRound();
                }
            }
        }

    然后,我们添加 endOfGame() 和 endOfRound() 函数。关键字 “internal” 与 “private” 是一样的,唯一的区别是 internal 函数可以由其他合约继承(因为Solidity与其他面向对象语言相似),而 private 函数不能继承。

        function endOfRound() internal {
            wrestler1Played = false;
            wrestler2Played = false;
    
            EndOfRoundEvent(wrestler1Deposit, wrestler2Deposit);
        }
    
        function endOfGame(address winner) internal {
            gameFinished = true;
            theWinner = winner;
    
            gains = wrestler1Deposit + wrestler2Deposit;
            EndOfWrestlingEvent(winner, gains);
        }

    请注意,我们不是直接把钱交给赢家,在此情况下这并不重要,因为赢家会把该合约所有的钱提取出来;而在其他情况下,当多个用户要把合约中的以太币提取出来,使用 withdraw 模式会更安全,可以避免重入。

    简单地说,如果多个用户都可以从合约中提取资金,那么任谁都能一次性多次调用 withdraw 函数并多次得到报酬。所以我们需要以这样一种方式来编写我们的取款功能:在他继续得到报酬之前,他应得的数额会作废。

    它看起来像这样:

        function withdraw() public {
            require(gameFinished && theWinner == msg.sender);
    
            uint amount = gains;
    
            gains = 0;
            msg.sender.transfer(amount);
        }

    就是这样。你可以在以下链接中找到整个代码段:

    devzl/ethereum-walkthrough-1

    使用IDE

    现在复制代码段,在浏览器的新标签页中打开 Remix IDE

    你可以直接在浏览器上使用 Remix,它有很多有意思的功能,这些功能你在别的地方几乎找不到。

    点击页面左上方的“+”按钮,创建一个名为“Wrestling.sol”的新文件,然后粘贴你在上面的 github中找到的代码。

    2

    最后会有一些语法高亮显示。Github 暂不支持 Solidity .sol 扩展。

    在页面的右侧,你可以找到很多有意思的选项卡,比如Analysis,它会显示错误和建议。这个工具留给你好好探索。我还是想向你演示一下,即使在接下来的教程中我们会使用其他的工具。但正如我之前所说的,本系列教程的目标是连接这些信息点并向你展示它们是如何在一起协同工作的,你可以自由决定是否在浏览器上使用IDE。如果你愿意的话,邀请你读一下 Remix的文档。

    或者,你可以阅读这些文档来熟悉 Solidity 。

    在接下来的教程中,我们将了解如何将智能合约部署到两种测试网络中,探索 truffle, ganache 和 geth 以及它们是如何一起协同工作的。

    如何你喜欢这一讲,你可以在twitter 上关注我@dev_zl.

    点击这里,阅读第2讲。


    原文链接: https://hackernoon.com/ethereum-development-walkthrough-part-1-smart-contracts-b3979e6e573e
    作者: dev_zl
    翻译&校对: 俊颖 & Elisa

    转载请注明:比特阁 » 以太坊开发演练,Part-1:智能合约

    喜欢 0

还没有人抢沙发呢~